< < Feb 2008 > >
S	M	T	W	T	F	S
					1	2
3	4	5	6	7	8	9
10	11	12	13	14	15	16
17	18	19	20	21	22	23
24	25	26	27	28	29

You are not signed in.
Sign in

Entries By Topic
·All Topics
·Classic ASP
·CSS
·Databases
·eBay/PayPal
·General
·Hardware
·Web Security
·Windows XP

Recent Entries
·eBay encourage/force you to lose money on postage
·CAPCTHAs and alternatives
·Obtaining Image Properties in ASP Without a Component
·New Microsoft Hotmail good reason not to use Microsoft Explorer
·Why are most real estate agents so bad at selling online
·Classic ASP Title Case
·Does stopfax.com.au really stop junk faxes?
·SQL Injection Protection - b.js
·Unfair eBay fees for used cars
·100% CSS Layout

John's Blog

VBScript Class to Send Mail With CDOSYS

Posted at: February 16, 2008
Related Topic(s): Classic ASP

This is my first attempt at a VBScript class.

It allows full control of the CDO Message object.

You can create a new instance of the class with the following:

Dim clsSendMail
Set clsSendMail = New SendMail

Then add the various properties of the email:

clsSendMail.SendTo = "test@test.com"
clsSendMail.From = "test@test.com"
clsSendMail.Subject = "Test Message"

Next you choose what type of mail you are going to send: plain text, HTML or from a URL or local file.

Type	Property/Method	Syntax
Plain Text	TextBody	clsSendMail.TextBody = "message here"
HTML	HTMLBody	clsSendMail.HTMLBody = "<b>html</b> message here"
URL	CreateMHTMLBody	Call clsSendMail.CreateMHTMLBody "http://www.url.com/pagename.htm"
Local File	CreateMHTMLBody	Call clsSendMail.CreateMHTMLBody "file://c:/mydocuments/test.htm"

To add an attachment use the following:

Call clsSendMail.AddAttachment "c:\mydocuments\test.txt"

To embed files in your message use:

clsSendMail.AddRelatedBodyPart "/older/imagefile.gif", "image1.gif"

This can then be included in your HTMLBody by referencing the second parameter as the CID, for example:

<img src="cid:image1.gif">

You can also set a SMTP server and port if neccessary:

Call clsSendMail.SMTPServer "mail.test.com", 25

SendMail Class

Class SendMail

Private objCDOMessage
	Private objCDOBodyPart

Private strTo
	Private strFrom
	Private strCC
	Private strBCC
	Private strSubject
	Private strTextBody
	Private strHTMLBody

Private Sub Class_Initialize()
		Set objCDOMessage = CreateObject("CDO.Message")
	End Sub

Private Sub Class_Terminate()
		Set objCDOMessage = Nothing
	End Sub

Public Property Let SendTo(strParam1)
		strTo = strParam1
	End Property

Public Property Let From(strParam1)
		strFrom = strParam1
	End Property

Public Property Let CC(strParam1)
		strCC = strParam1
	End Property

Public Property Let BCC(strParam1)
		strBCC = strParam1
	End Property

Public Property Let Subject(strParam1)
		strSubject = strParam1
	End Property

Public Property Let TextBody(strParam1)
		strTextBody = strParam1
	End Property

Public Property Let HTMLBody(strParam1)
		strHTMLBody = strParam1
	End Property

Public Sub CreateMHTMLBody(strParam1)
		objCDOMessage.CreateMHTMLBody strParam1
	End Sub

Public Sub AddAttachment(strParam1)
		objCDOMessage.AddAttachment strParam1
	End Sub

Public Sub SMTPServer(strParam1, intParam2)
		objCDOMessage.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/sendusing") = 2
		objCDOMessage.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserver") = strParam1
		objCDOMessage.Configuration.Fields.Item("http://schemas.microsoft.com/cdo/configuration/smtpserverport") = intParam2
		objCDOMessage.Configuration.Fields.Update
	End Sub

Public Sub AddRelatedBodyPart(strParam1, strParam2)
		Set objCDOBodyPart = objCDOMessage.AddRelatedBodyPart(Server.MapPath(strParam1), strParam2, 1)
		objCDOBodyPart.Fields.Item("urn:schemas:mailheader:Content-ID") = "<" & strParam2 & ">"
		objCDOBodyPart.Fields.Update
	End Sub

Public Sub Send()
		If strTo <> "" Then objCDOMessage.To = strTo
		If strFrom <> "" Then objCDOMessage.From = strFrom
		If strCC <> "" Then objCDOMessage.CC = strCC
		If strBCC <> "" Then objCDOMessage.BCC = strBCC
		If strSubject <> "" Then objCDOMessage.Subject = strSubject
		If strTextBody <> "" Then objCDOMessage.TextBody = strTextBody
		If strHTMLBody <> "" Then objCDOMessage.HTMLBody = strHTMLBody
		objCDOMessage.Send
	End Sub
End Class

View Comments (0) | Add Comment | Permalink

Newer | Latest | Older

Free automotive classifieds, reviews, etc

Car and motorcycle books and repair manuals

ASP Hosting and Domain Names

For cheap asp and asp.net hosting I recommend CrystalTech, for cheap .com domains Cheeky Domains, or for .com.au domains Name Scout.

[Oztion is an Australian auction website which offers no listing fees]